plugins {
    kotlin("jvm")
    kotlin("kapt")
    id("com.github.johnrengelman.shadow")
}

group = rootProject.group
version = rootProject.version

repositories {
    mavenCentral()
    jcenter()
    maven("https://jitpack.io")
}

dependencies {
    // Kotlin
    implementation(KotlinX.coroutines.core)
    implementation(KotlinX.coroutines.jdk8) // TODO: What is jdk9?

    // Uranos
    implementation(project(":uranos-api"))
    implementation(project(":uranos-packets"))
    implementation(project(":uranos-packet-codecs"))
    implementation(project(":uranos-nbt"))

    // Logging
    implementation("org.slf4j:slf4j-api:_")
    implementation("ch.qos.logback:logback-classic:_")
    implementation("de.moritzruth:khalk:_")

    // Netty
    implementation("io.netty:netty-handler:_")
    implementation("io.netty:netty-buffer:_")
    implementation("io.netty:netty-codec:_")
    implementation("io.netty:netty-transport:_")
    implementation("io.netty:netty-transport-native-epoll:_")
    implementation("io.netty:netty-transport-native-kqueue:_")

    // Other
    implementation(Square.okHttp3.okHttp)
    implementation("com.sksamuel.hoplite:hoplite-core:_")
    implementation("com.sksamuel.hoplite:hoplite-yaml:_")
    kapt(Square.moshi.kotlinCodegen)

    // Testing
    testImplementation(Testing.Strikt.core)
    testImplementation(Testing.junit.api)
    testRuntimeOnly(Testing.junit.engine)
}

tasks {
    compileKotlin {
        kotlinOptions.freeCompilerArgs += "-Xopt-in=kotlin.RequiresOptIn"
    }

    test {
        useJUnitPlatform()
    }

    shadowJar {
        archiveClassifier.set(null as String?)

        @Suppress("UnstableApiUsage")
        manifest {
            this.attributes(
                "Main-Class" to "space.uranos.UranosServer",
                "Implementation-Version" to project.version
            )
        }
    }
}